UNIFIKASI DAN PENGENDALIAN PROGRAM (Contoh Program PROLOG) Logika Informatika

Tujuan :

1. Memahami tentang unifikasi

I. Unifikasi

            Unifikasi adalah suatu proses pemadanan atau pembandingan untuk mencari jawaban seperti nilai suatu variabel. Melalui unifikasi suatu variabel diberi nilai.

            Beberapa hal tentang unifikasi :

a. Unifikasi terjadi pada sesama argumen yang posisinya sama.

b. Nama dan aritas predikat harus sama

c. Unifikasi terjadi bersamaan pada semua argumen.

d. Hasil unifikasi tidak boleh mengakibatkan variabel mempunyai nilai ganda atau bertentangan.

e. Domain objek majemuk dapat berunifikasi dengan variabel biasa seperti s(A) dengan C.

f. Argumen objek majemuk dapat berunifikasi dengan variabel biasa seperti s(x) dengan s( C ).

g. Bisa terjadi unifikasi dengan aturan.

contoh :

domains

      jenis,pabrik =symbol

      penumpang=integer

predicates

      pembuat(pabrik,jenis)

      pesawat(jenis,penumpang)

      pesawat_kecil(jenis)

clauses

      pembuat(boeing,boeing_747).

      pembuat(fokker,f28).

      pembuat(iptn,n250).

      pesawat(boeing_747,500).

      pesawat(n250,50).

      pesawat_kecil(Jenis):-

            pembuat(_,Jenis),

            pesawat(Jenis,JmlPen),

            JmlPen>100.      

Apabila kiat meniliskan pada goal:

            pesawat_kecil(Jenis)

maka Turbo Prolog akan menjawab :

            Jenis = n250

            1 solutions

            Pada saat Turbo prolog menerima goal tadi, maka Turbo Prolog melakukan pemanggilan klausa pesawat_kecil yang berupa aturan. Pencarian jawaban akan berhasil bila tubuh klausa terpenuhi yaitu :

• Pertama, Turbo Prolog akan memanggil sub klausa penbuat(_,Jenis). Di sini nama pabrik tidak dipermasalahkan karena menggunakan variabel tak bernama. Oleh karena itu hanya variabel Jenis yang diinstantiasikan dengan boeing_747. Turbo Prolog kembali dari memanggil klausa pembuat dengan hasil Jenis = boeing_747.
• Kedua, Turbo Prolog memanggil sub klausa pesawat(boeing_747,JmlPen), yang kemudian kembali dengan JmlPen = 500.
• Ketiga, Turbo Prolog melakukan pembandingan 500<100. Hasilnya gagal.
• Keempat, kegagalan ini menyebabkan Turbo Prolog mencari jawaban yang lain sehingga diperoleh Jenis = n250 dan JmlPen =50. Maka Turbo Prolog akan menjawab seperti di atas.

Untuk selanjutnya pahami contoh program berikut ini :

domains

   name = symbol

   gpa  = real

predicates

   honor_student(name)

   student(name, gpa)

   probation(name)

clauses

   honor_student(Name):-

      student(Name, GPA),

      GPA>=3.5,

      not(probation(Name)).

   student("Betty Blue", 3.5).

   student("David Smith", 2.0).

   student("John Johnson", 3.7).

   probation("Betty Blue").

   probation("David Smith").

Ketikkan pada bagian goal : honor_student(Name)

II. Lacak Balik.

            Dalam menyelesaikan permasalahan, Turbo Prolog akan mencari semua kemungkinan jawaban. Apabila menemui kegagalan, Turbo Prolog akan melacak balik.(analog dengan pencarian suatu alamat).

            Dalam pelacakannya, Turbo Prolog menggunakan metode pencarian terdalam (depth-first search).

            Perhatikan contoh berikut ini :

domains

      orang,makanan,rasa = symbol

predicates

      suka(orang,makanan)

      berasa(makanan,rasa)

      makanan(makanan)

clauses

      suka(didit,X):-

      makanan(X),berasa(X,keju).

      berasa(roti,tawar).

      berasa(pia,coklat).

      berasa(pia,susu).

      berasa(pia,keju).

      makanan(roti).

      makanan(kripik).

      makanan(pia).

goal

      suka(didit,Apa),

            write(" Didit suka makan ",Apa).

Pada saat program dijalankan, Turbo Prolog akan mencari klausa suka dari atas. Dalam hal ini, program akan memanggil klausa suka dan didapati aturan :

            suka(didit,X) :- makanan(X),berasa(X,keju).

Pada saat itu terjadi unifikasi antara variabel Apa dengan X yang keduanya masih bebas. Aturan di atas terdiri dari dua sub-goal :makanan dan berasa, keduanya harus terpenuhi. Maka Prolog mulai memanggil sub-goal paling atas hingga paling bawah. Pertama, prolog melakukan unifikasi sub goal makanan(X) dengan kumpulan klausa makanan yang teratas yakni :makanan(roti). Unifikasi berhasil menyebabkan X terikat dengan roti. Di sini Prolog mencatat titik lacak balik untuk klausa makanan, karena ada klausa makanan lain, yaitu makanan(kripik). Prolog kembali dengan berhasil(X=roti), sehingga Prolog melanjutkan ke subgoal berikutnya :berasa(X,keju), yang diartikan berasa(roti,keju).

Di sini Prolog mengalami kegagalan karena tidak menemukan fakta berasa(roti,keju). Kemudian Prolog memeriksa catatan titik balik dan ada pada makanan(kripik), sehingga terjadi unifikasi antara variabel X dengan kripik. Pada saat ini Prolog juga mencatat titik lacak balik di makanan(pia).

Kemudian Prolog mencari fakta berasa(kripik,keju) yang juga mengalami kegagalan. Sehingga Prolog memulai pelacakan kembali dari titik balik terakhir yaitu pada makanan(pia). Yang kemudian Prolog melanjutkan ke subgoal berasa(pia,keju) dan berhasil karena ada fakta tersebut.

TUGAS

Jelaskan bagaimana Turbo Prolog menyelesaikan kasus pembunuhan ini.

domains

   name, sex, occupation, object, vice, substance = symbol

   age=integer

predicates

   person(name, age, sex, occupation)

   had_affair(name, name)

   killed_with(name, object)

   killed(name)

   killer(name)

   motive(vice)

   smeared_in(name, substance)

   owns(name, object)

   operates_identically(object, object)

   owns_probably(name, object)

   suspect(name)

/* * * Facts about the murder * * */

clauses

   person(bert, 55, m, carpenter).

   person(allan, 25, m, football_player).

   person(allan, 25, m, butcher).

   person(john, 25, m, pickpocket).

   had_affair(barbara, john).

   had_affair(barbara, bert).

   had_affair(susan, john).

   killed_with(susan, club).

   killed(susan).

   motive(money).

   motive(jealousy).

   motive(righteousness).

   smeared_in(bert, blood).

   smeared_in(susan, blood).

   smeared_in(allan, mud).

   smeared_in(john, chocolate).

   smeared_in(barbara, chocolate).

   owns(bert, wooden_leg).

   owns(john, pistol).

/* * * Background knowledge * * */

   operates_identically(wooden_leg, club).

   operates_identically(bar, club).

   operates_identically(pair_of_scissors, knife).

   operates_identically(football_boot, club).

   owns_probably(X, football_boot) :-

      person(X, _, _, football_player).

   owns_probably(X, pair_of_scissors) :-

      person(X, _, _, hairdresser).

   owns_probably(X, Object) :-

      owns(X, Object).

/* * * * * * * * * * * * * * * * * * * * * * *

 * Suspect all those who own a weapon with   *

 * which Susan could have been killed.       *

 * * * * * * * * * * * * * * * * * * * * * * */

   suspect(X) :-

      killed_with(susan, Weapon) ,

      operates_identically(Object, Weapon) ,

      owns_probably(X, Object).

/* * * * * * * * * * * * * * * * * * * * * * * * * *

 * Suspect men who have had an affair with Susan.  *

 * * * * * * * * * * * * * * * * * * * * * * * * * */

   suspect(X) :-

      motive(jealousy) ,

      person(X, _, m, _) ,

      had_affair(susan, X).

/* * * * * * * * * * * * * * * * * * * * *

 * Suspect females who have had an       *

 * affair with someone that Susan knew.  *

 * * * * * * * * * * * * * * * * * * * * */

   suspect(X) :-

      motive(jealousy) ,

      person(X, _, f, _) ,

      had_affair(X, Man) ,

      had_affair(susan, Man).

/* * * * * * * * * * * * * * * * * * * * * * * * * * *

 * Suspect pickpockets whose motive could be money.  *

 * * * * * * * * * * * * * * * * * * * * * * * * * * */

   suspect(X) :-

      motive(money) , person(X, _, _, pickpocket).

   killer(Killer) :-

      person(Killer, _, _, _) ,

      killed(Killed) ,

      Killed <> Killer , /* It is not a suicide */

      suspect(Killer) ,

      smeared_in(Killer, Goo) ,

      smeared_in(Killed, Goo).

Goal

   killer(Killer),

   write(“ Pembunuhnya adalah “, Killer).

 Download Disini

Download